Keep us posted!
If it helps this website is handy for compressing gifs in case you want to experiment with dropping the size of your 480x480 file.
1 Like
AH yes that’s the one I used, too. I can’t drop the pixel size, but it helped me optimize it in other ways. Thank you.
1 Like
When you say it crashes, does it auto reboot and re run the bad code, or is it just freezing?
Not sure. It used to do a complete reboot, showing the “hello world” stuff again. But now I hear the Windows disconnect/reconnect sound after the “hello world”, then the screen stays black.
For testing see how you go increasing the size of the gif bit by bit to see if you van find a size that always works and the size at which it will fail.
I tried a large variety provided by my programmer on Fiverr. The only one that worked was ‘portal2_image.h’, which was the only 320x320. All the others are 480x480 or somewhere in between:
To help debug, you could try to add a wait for some sort of input befor loadimg the gif, then ensure debug is working then provide the inout to continue and load the gif.
As per your suggestion and Jeff’s, I’ve added wait commands and some additional serial monitor prints to see what’s going on just before the crash.
Here are the results when I use ‘new_portal_low_mem1.h’:
Any chance you can post your code ?
Here’s the current version of the code, which hasn’t changed much since the original (aside from the debug code at the bottom):
#include <Arduino_GFX_Library.h>
#include <AnimatedGIF.h>
#include "new_portal_low_mem1.h"
#define DISPLAY_WIDTH 480
#define DISPLAY_HEIGHT 480
Arduino_XCA9554SWSPI *expander = new Arduino_XCA9554SWSPI(
PCA_TFT_RESET, PCA_TFT_CS, PCA_TFT_SCK, PCA_TFT_MOSI,
&Wire, 0x3F); //I2C expander used for BACKLIGHT LED CONTROL
Arduino_ESP32RGBPanel *rgbpanel = new Arduino_ESP32RGBPanel(
TFT_DE, TFT_VSYNC, TFT_HSYNC, TFT_PCLK,
TFT_R1, TFT_R2, TFT_R3, TFT_R4, TFT_R5,
TFT_G0, TFT_G1, TFT_G2, TFT_G3, TFT_G4, TFT_G5,
TFT_B1, TFT_B2, TFT_B3, TFT_B4, TFT_B5,
1 /* hync_polarity */, 46 /* hsync_front_porch */, 2 /* hsync_pulse_width */, 44 /* hsync_back_porch */,
1 /* vsync_polarity */, 50 /* vsync_front_porch */, 16 /* vsync_pulse_width */, 16 /* vsync_back_porch */);
Arduino_RGB_Display *gfx = new Arduino_RGB_Display(
// 2.8" round
DISPLAY_WIDTH /* width */, DISPLAY_HEIGHT /* height */, rgbpanel, 0 /* rotation */, true /* auto_flush */,
expander, GFX_NOT_DEFINED /* RST */, TL028WVC01_init_operations, sizeof(TL028WVC01_init_operations));
AnimatedGIF gif;
int x_offset = 0;
int y_offset = 0;
// Draw a line of image directly on the TFT
void GIFDraw(GIFDRAW *pDraw){
uint8_t *s;
uint16_t *d, *usPalette, usTemp[320];
int x, y, iWidth;
iWidth = pDraw->iWidth;
if (iWidth + pDraw->iX > DISPLAY_WIDTH)
iWidth = DISPLAY_WIDTH - pDraw->iX;
usPalette = pDraw->pPalette;
y = pDraw->iY + pDraw->y; // current line
if (y >= DISPLAY_HEIGHT || pDraw->iX >= DISPLAY_WIDTH || iWidth < 1)
return;
s = pDraw->pPixels;
if (pDraw->ucDisposalMethod == 2) // restore to background color
{
for (x=0; x<iWidth; x++)
{
if (s[x] == pDraw->ucTransparent)
s[x] = pDraw->ucBackground;
}
pDraw->ucHasTransparency = 0;
}
// Apply the new pixels to the main image
if (pDraw->ucHasTransparency) // if transparency used
{
uint8_t *pEnd, c, ucTransparent = pDraw->ucTransparent;
int x, iCount;
pEnd = s + iWidth;
x = 0;
iCount = 0; // count non-transparent pixels
while(x < iWidth)
{
c = ucTransparent-1;
d = usTemp;
while (c != ucTransparent && s < pEnd)
{
c = *s++;
if (c == ucTransparent) // done, stop
{
s--; // back up to treat it like transparent
}
else // opaque
{
*d++ = usPalette[c];
iCount++;
}
} // while looking for opaque pixels
if (iCount) // any opaque pixels?
{
gfx->draw16bitRGBBitmap(pDraw->iX+x+x_offset, y+y_offset, usTemp, iCount, 1);
x += iCount;
iCount = 0;
}
// no, look for a run of transparent pixels
c = ucTransparent;
while (c == ucTransparent && s < pEnd)
{
c = *s++;
if (c == ucTransparent)
iCount++;
else
s--;
}
if (iCount)
{
x += iCount; // skip these
iCount = 0;
}
}
}
else
{
s = pDraw->pPixels;
// Translate the 8-bit pixels through the RGB565 palette (already byte reversed)
for (x=0; x<iWidth; x++)
usTemp[x] = usPalette[*s++];
gfx->draw16bitRGBBitmap(pDraw->iX+x_offset, y+y_offset, usTemp, iWidth, 1);
}
} /* GIFDraw() */
void setup(void)
{
Serial.begin(115200);
#ifdef GFX_EXTRA_PRE_INIT
GFX_EXTRA_PRE_INIT();
#endif
Serial.println("Starting RGB screen");
// Init Display
Wire.setClock(400000); // speed up I2C for expander
if (!gfx->begin()) {
Serial.println("gfx->begin() failed!!!");
while (1) yield();
}
gfx->fillScreen(BLACK);
expander->pinMode(PCA_TFT_BACKLIGHT, OUTPUT);
expander->digitalWrite(PCA_TFT_BACKLIGHT, HIGH); //turn on backlight led
//TEST CODE TO MAKE SURE DISPLAY IS OK BEGINS
Serial.println("Hello!");
gfx->fillScreen(BLACK);
gfx->setCursor(100, gfx->height() / 2 - 75);
gfx->setTextSize(5);
gfx->setTextColor(WHITE);
gfx->println("Hello World!");
Serial.println("Hello in RED!");
gfx->setCursor(100, gfx->height() / 2 - 25);
gfx->setTextColor(RED);
gfx->println("RED");
Serial.println("Hello in GREEEN!");
gfx->setCursor(100, gfx->height() / 2 + 25);
gfx->setTextColor(GREEN);
gfx->println("GREEN");
Serial.println("Hello in BL;UE!");
gfx->setCursor(100, gfx->height() / 2 + 75);
gfx->setTextColor(BLUE);
gfx->println("BLUE");
delay(1000);
gfx->fillScreen(BLACK);
//TEST CODE TO MAKE SURE DISPLAY IS OK ENDS
}
void loop(){
delay(5000);
// put your main code here, to run repeatedly:
if (gif.open((uint8_t *)gif_data, sizeof(gif_data), GIFDraw)){
Serial.printf("Successfully opened GIF; Canvas size = %d x %d\n", gif.getCanvasWidth(), gif.getCanvasHeight());
if( gif.getCanvasWidth() < DISPLAY_WIDTH || gif.getCanvasHeight() < DISPLAY_HEIGHT){
x_offset = (DISPLAY_WIDTH - gif.getCanvasWidth()) / 2;
y_offset = (DISPLAY_HEIGHT - gif.getCanvasHeight())/ 2;
}
Serial.print("Total heap: ");
Serial.println(ESP.getHeapSize());
Serial.print("Free heap: ");
Serial.println(ESP.getFreeHeap());
Serial.print("Total PSRAM: ");
Serial.println(ESP.getPsramSize());
Serial.print("Free PSRAM: ");
Serial.println(ESP.getFreePsram());
delay(5000);
while (gif.playFrame(true, NULL))
{
}
gif.close();
}
}
I tried uploading one of the GIFs here on the forum, but I get this error:
The PSRAM functions may or may not work if the PSRAM has not been initialized.
How do I use this? I’ll forward the instructions to my programmer. I myself am at my mental limit, lol.
If it’s not going to use 16MB of flash and 8MB of PSRAM then it’s the wrong library for this device.
Which library do you recommend? I have no knowledge of any of them or their capabilities.
that fact the the show memory gave what looks to be the correct values for the PSRAM, I would say it is initialized OK.
And its using 460,948 Bytes, so seems to be in use.
1 Like
Can you make your code like this and see if it adds anything to the debug, if so, what.
int returnvalue = 1;
while (returnvalue)
{
returnvalue = gif.playFrame(true, NULL);
Serial.print(returnvalue );
}
gif.close();
What I am trying to capture is whats might be happening in the call to show the gif and how many times it may loop (if any) before it stops.
1 Like
I changed the code as instructed, uploaded and ran it. Then I checked on the serial monitor and nothing had changed, nothing additional was printed. Device still crashed and went black like before.
Im on the train atm so wont be able to check much.
If there was no print of then return value, then its either crashing faster yhen the print can clock out or it crashs in the function call…
So bit by bit we need to home in on the issue.
1 Like
I tried using your code with a GIF I knew previously works instead:
This was the 320x320 GIF.
void loop(){
delay(5000);
// put your main code here, to run repeatedly:
if (gif.open((uint8_t *)gif_data, sizeof(gif_data), GIFDraw)){
Serial.printf("Successfully opened GIF; Canvas size = %d x %d\n", gif.getCanvasWidth(), gif.getCanvasHeight());
if( gif.getCanvasWidth() < DISPLAY_WIDTH || gif.getCanvasHeight() < DISPLAY_HEIGHT){
x_offset = (DISPLAY_WIDTH - gif.getCanvasWidth()) / 2;
y_offset = (DISPLAY_HEIGHT - gif.getCanvasHeight())/ 2;
}
Serial.print("Total heap: ");
Serial.println(ESP.getHeapSize());
Serial.print("Free heap: ");
Serial.println(ESP.getFreeHeap());
Serial.print("Total PSRAM: ");
Serial.println(ESP.getPsramSize());
Serial.print("Free PSRAM: ");
Serial.println(ESP.getFreePsram());
delay(5000);
/*
while (gif.playFrame(true, NULL))
{
}
gif.close();*/
int returnvalue = 1;
while (returnvalue)
{
returnvalue = gif.playFrame(true, NULL);
Serial.print(returnvalue );
}
gif.close();
}
The device boots as normal, waits 10 seconds, then plays just the first 4 frames, before freezing on the 5th frame. After about 16 seconds it starts those first 4 frames again. Really weird!
Not that previously this GIF would loop successfully.
Is that 0 in the print out what you were referring to earlier?
The 0 should be some event to tell rhe main while loop its all done. But it could be a zero frame as well in the code i was looking at. Other values would indicate other issues.
Note the serial print will have some delay on the loop. But we are tryimg to find the error so we accept some things will be affected
1 Like
Is the 320 here the issue?
EDIT: Guess what guys… I think that was it. Lol. Hold fire, doing some final testing.
Good news. That was it. That was the bug. A simple ‘320’ in the earlier code needed to be changed to ‘480’. I’d like to thank you all for your patience and assistance. I’ve been trying to get this working for months. I don’t think I ever want to work with Adafruit devices again after this, haha.
Feel free to close the post.
Well done… Its a good feeling to get it working.
What I hope one of your key take away form this would be to just work the problem and see what does what in the code. As long as you have all the source files, you can normally find where the issue is. e.g. “did we get this far into the code”
Anyway… good luck as you move forwards and now you know it “can” be done 
1 Like
